pleroma/lib/pleroma/web/activity_pub/mrf.ex

# Pleroma: A lightweight social networking server
# Copyright © 2017-2023 Pleroma Authors <https://pleroma.social/>
# SPDX-License-Identifier: AGPL-3.0-only

defmodule Pleroma.Web.ActivityPub.MRF do
  require Logger

  @behaviour Pleroma.Web.ActivityPub.MRF.PipelineFiltering

  @mrf_config_descriptions [
    %{
      group: :pleroma,
      key: :mrf,
      tab: :mrf,
      label: "MRF",
      type: :group,
      description: "General MRF settings",
      children: [
        %{
          key: :policies,
          type: [:module, {:list, :module}],
          description:
            "A list of MRF policies enabled. Module names are shortened (removed leading `Pleroma.Web.ActivityPub.MRF.` part), but on adding custom module you need to use full name.",
          suggestions: {:list_behaviour_implementations, Pleroma.Web.ActivityPub.MRF.Policy}
        },
        %{
          key: :transparency,
          label: "MRF transparency",
          type: :boolean,
          description:
            "Make the content of your Message Rewrite Facility settings public (via nodeinfo)"
        },
        %{
          key: :transparency_exclusions,
          label: "MRF transparency exclusions",
          type: {:list, :tuple},
          key_placeholder: "instance",
          value_placeholder: "reason",
          description:
            "Exclude specific instance names from MRF transparency. The use of the exclusions feature will be disclosed in nodeinfo as a boolean value. You can also provide a reason for excluding these instance names. The instances and reasons won't be publicly disclosed.",
          suggestions: [
            "exclusion.com"
          ]
        }
      ]
    }
  ]

  @default_description %{
    label: "",
    description: ""
  }

  @required_description_keys [:key, :related_policy]

  def filter_one(policy, message) do
    Code.ensure_loaded(policy)

    should_plug_history? =
      if function_exported?(policy, :history_awareness, 0) do
        policy.history_awareness()
      else
        :manual
      end
      |> Kernel.==(:auto)

    if not should_plug_history? do
      policy.filter(message)
    else
      main_result = policy.filter(message)

      with {_, {:ok, main_message}} <- {:main, main_result},
           {_,
            %{
              "formerRepresentations" => %{
                "orderedItems" => [_ | _]
              }
            }} = {_, object} <- {:object, message["object"]},
           {_, {:ok, new_history}} <-
             {:history,
              Pleroma.Object.Updater.for_each_history_item(
                object["formerRepresentations"],
                object,
                fn item ->
                  with {:ok, filtered} <- policy.filter(Map.put(message, "object", item)) do
                    {:ok, filtered["object"]}
                  else
                    e -> e
                  end
                end
              )} do
        {:ok, put_in(main_message, ["object", "formerRepresentations"], new_history)}
      else
        {:main, _} -> main_result
        {:object, _} -> main_result
        {:history, e} -> e
      end
    end
  end

  def filter(policies, %{} = message) do
    policies
    |> Enum.reduce({:ok, message}, fn
      policy, {:ok, message} -> filter_one(policy, message)
      _, error -> error
    end)
  end

  def filter(%{} = object), do: get_policies() |> filter(object)

  def id_filter(policies, id) when is_binary(id) do
    policies
    |> Enum.filter(&function_exported?(&1, :id_filter, 1))
    |> Enum.all?(& &1.id_filter(id))
  end

  def id_filter(id) when is_binary(id), do: get_policies() |> id_filter(id)

  @impl true
  def pipeline_filter(%{} = message, meta) do
    object = meta[:object_data]
    ap_id = message["object"]

    if object && ap_id do
      with {:ok, message} <- filter(Map.put(message, "object", object)) do
        meta = Keyword.put(meta, :object_data, message["object"])
        {:ok, Map.put(message, "object", ap_id), meta}
      else
        {err, message} -> {err, message, meta}
      end
    else
      {err, message} = filter(message)

      {err, message, meta}
    end
  end

  def get_policies do
    Pleroma.Config.get([:mrf, :policies], [])
    |> get_policies()
    |> Enum.concat([Pleroma.Web.ActivityPub.MRF.HashtagPolicy])
  end

  defp get_policies(policy) when is_atom(policy), do: [policy]
  defp get_policies(policies) when is_list(policies), do: policies
  defp get_policies(_), do: []

  @spec subdomains_regex([String.t()]) :: [Regex.t()]
  def subdomains_regex(domains) when is_list(domains) do
    for domain <- domains do
      {prefix, rest} =
        case domain do
          "*." <> rest -> {"(.*\\.)?", rest}
          _ -> {"", domain}
        end

      ~r<^#{prefix}#{Regex.escape(rest)}$>i
    end
  end

  @spec subdomain_match?([Regex.t()], String.t()) :: boolean()
  def subdomain_match?(domains, host) do
    Enum.any?(domains, fn domain -> Regex.match?(domain, host) end)
  end

  @doc """
  Returns a function that is false for a host if SimplePolicy is enabled and
  rejects it, or has an accept list without it. Used for deliveries and signed
  fetches, not only for incoming activities. Build it once and reuse it: it
  compiles the instance lists.
  """
  @spec instance_filter() :: (String.t() | nil -> boolean())
  def instance_filter do
    if Pleroma.Web.ActivityPub.MRF.SimplePolicy in get_policies() do
      reject = simple_policy_domains(:reject)
      accept = simple_policy_domains(:accept)

      fn
        host when is_binary(host) ->
          not subdomain_match?(reject, host) and (accept == [] or subdomain_match?(accept, host))

        _ ->
          false
      end
    else
      &is_binary/1
    end
  end

  @spec instance_allowed?(String.t() | nil) :: boolean()
  def instance_allowed?(host), do: instance_filter().(host)

  defp simple_policy_domains(key) do
    Pleroma.Config.get([:mrf_simple, key], [])
    |> instance_list_from_tuples()
    |> subdomains_regex()
  end

  @spec instance_list_from_tuples([{String.t(), String.t()}]) :: [String.t()]
  def instance_list_from_tuples(list) do
    Enum.map(list, fn {instance, _} -> instance end)
  end

  def describe(policies) do
    {:ok, policy_configs} =
      policies
      |> Enum.reduce({:ok, %{}}, fn
        policy, {:ok, data} ->
          {:ok, policy_data} = policy.describe()
          {:ok, Map.merge(data, policy_data)}

        _, error ->
          error
      end)

    mrf_policies =
      get_policies()
      |> Enum.map(fn policy -> to_string(policy) |> String.split(".") |> List.last() end)

    exclusions = Pleroma.Config.get([:mrf, :transparency_exclusions])

    base =
      %{
        mrf_policies: mrf_policies,
        exclusions: length(exclusions) > 0
      }
      |> Map.merge(policy_configs)

    {:ok, base}
  end

  def describe, do: get_policies() |> describe()

  def config_descriptions do
    Pleroma.Web.ActivityPub.MRF.Policy
    |> Pleroma.Docs.Generator.list_behaviour_implementations()
    |> config_descriptions()
  end

  def config_descriptions(policies) do
    Enum.reduce(policies, @mrf_config_descriptions, fn policy, acc ->
      Code.ensure_loaded(policy)

      if function_exported?(policy, :config_description, 0) do
        description =
          @default_description
          |> Map.merge(policy.config_description())
          |> Map.put(:group, :pleroma)
          |> Map.put(:tab, :mrf)
          |> Map.put(:type, :group)

        if Enum.all?(@required_description_keys, &Map.has_key?(description, &1)) do
          [description | acc]
        else
          Logger.warning(
            "#{policy} config description doesn't have one or all required keys #{inspect(@required_description_keys)}"
          )

          acc
        end
      else
        Logger.debug(
          "#{policy} is excluded from config descriptions, because does not implement `config_description/0` method."
        )

        acc
      end
    end)
  end
end