pleroma/test/pleroma/web/activity_pub/mrf_test.exs

# Pleroma: A lightweight social networking server
# Copyright © 2017-2023 Pleroma Authors <https://pleroma.social/>
# SPDX-License-Identifier: AGPL-3.0-only

defmodule Pleroma.Web.ActivityPub.MRFTest do
  use ExUnit.Case
  use Pleroma.Tests.Helpers

  alias Pleroma.Web.ActivityPub.MRF

  defp regexes_match!([], []), do: true

  defp regexes_match!([authority | authority_rest], [checked | checked_rest]) do
    authority.source == checked.source and regexes_match!(authority_rest, checked_rest)
  end

  defp regexes_match!(_, _), do: false

  test "subdomains_regex/1" do
    regexes = MRF.subdomains_regex(["unsafe.tld", "*.unsafe.tld"])

    assert regexes_match!(regexes, [~r/^unsafe\.tld$/i, ~r/^(.*\.)?unsafe\.tld$/i])
  end

  describe "subdomain_match/2" do
    test "common domains" do
      regexes = MRF.subdomains_regex(["unsafe.tld", "unsafe2.tld"])

      assert regexes_match!(regexes, [~r/^unsafe\.tld$/i, ~r/^unsafe2\.tld$/i])

      assert MRF.subdomain_match?(regexes, "unsafe.tld")
      assert MRF.subdomain_match?(regexes, "unsafe2.tld")

      refute MRF.subdomain_match?(regexes, "example.com")
    end

    test "wildcard domains with one subdomain" do
      regexes = MRF.subdomains_regex(["*.unsafe.tld"])

      assert regexes_match!(regexes, [~r/^(.*\.)?unsafe\.tld$/i])

      assert MRF.subdomain_match?(regexes, "unsafe.tld")
      assert MRF.subdomain_match?(regexes, "sub.unsafe.tld")
      refute MRF.subdomain_match?(regexes, "anotherunsafe.tld")
      refute MRF.subdomain_match?(regexes, "unsafe.tldanother")
    end

    test "wildcard domains with two subdomains" do
      regexes = MRF.subdomains_regex(["*.unsafe.tld"])

      assert regexes_match!(regexes, [~r/^(.*\.)?unsafe\.tld$/i])

      assert MRF.subdomain_match?(regexes, "unsafe.tld")
      assert MRF.subdomain_match?(regexes, "sub.sub.unsafe.tld")
      refute MRF.subdomain_match?(regexes, "sub.anotherunsafe.tld")
      refute MRF.subdomain_match?(regexes, "sub.unsafe.tldanother")
    end

    test "matches are case-insensitive" do
      regexes = MRF.subdomains_regex(["UnSafe.TLD", "UnSAFE2.Tld"])

      assert regexes_match!(regexes, [~r/^UnSafe\.TLD$/i, ~r/^UnSAFE2\.Tld$/i])

      assert MRF.subdomain_match?(regexes, "UNSAFE.TLD")
      assert MRF.subdomain_match?(regexes, "UNSAFE2.TLD")
      assert MRF.subdomain_match?(regexes, "unsafe.tld")
      assert MRF.subdomain_match?(regexes, "unsafe2.tld")

      refute MRF.subdomain_match?(regexes, "EXAMPLE.COM")
      refute MRF.subdomain_match?(regexes, "example.com")
    end

    test "dots only match dots" do
      regexes = MRF.subdomains_regex(["unsafe.tld", "*.other.tld"])

      refute MRF.subdomain_match?(regexes, "unsafextld")
      refute MRF.subdomain_match?(regexes, "otherxtld")
      refute MRF.subdomain_match?(regexes, "sub.otherxtld")
    end

    test "accidental wildcards and regex syntax match nothing" do
      regexes = MRF.subdomains_regex(["*unsafe.tld", "bad(.tld"])

      refute MRF.subdomain_match?(regexes, "unsafe.tld")
      refute MRF.subdomain_match?(regexes, "sub.unsafe.tld")
      refute MRF.subdomain_match?(regexes, "bad.tld")
    end
  end

  describe "instance_list_from_tuples/1" do
    test "returns a list of instances from a list of {instance, reason} tuples" do
      list = [{"some.tld", "a reason"}, {"other.tld", "another reason"}]
      expected = ["some.tld", "other.tld"]

      assert MRF.instance_list_from_tuples(list) == expected
    end
  end

  describe "describe/0" do
    test "it works as expected with noop policy" do
      clear_config([:mrf, :policies], [Pleroma.Web.ActivityPub.MRF.NoOpPolicy])

      expected = %{
        mrf_policies: ["NoOpPolicy", "HashtagPolicy"],
        mrf_hashtag: %{
          federated_timeline_removal: [],
          reject: [],
          sensitive: ["nsfw"]
        },
        exclusions: false
      }

      {:ok, ^expected} = MRF.describe()
    end

    test "it works as expected with mock policy" do
      clear_config([:mrf, :policies], [MRFModuleMock])

      expected = %{
        mrf_policies: ["MRFModuleMock", "HashtagPolicy"],
        mrf_module_mock: "some config data",
        mrf_hashtag: %{
          federated_timeline_removal: [],
          reject: [],
          sensitive: ["nsfw"]
        },
        exclusions: false
      }

      {:ok, ^expected} = MRF.describe()
    end
  end

  test "config_descriptions/0" do
    descriptions = MRF.config_descriptions()

    good_mrf = Enum.find(descriptions, fn %{key: key} -> key == :good_mrf end)

    assert good_mrf == %{
             key: :good_mrf,
             related_policy: "Fixtures.Modules.GoodMRF",
             label: "Good MRF",
             description: "Some description",
             group: :pleroma,
             tab: :mrf,
             type: :group
           }
  end

  describe "instance_allowed?/1" do
    setup do: clear_config([:mrf, :policies], [Pleroma.Web.ActivityPub.MRF.SimplePolicy])
    setup do: clear_config([:mrf_simple, :reject], [{"rejected.example", "spam"}])
    setup do: clear_config([:mrf_simple, :accept], [])

    test "is false for hosts rejected by SimplePolicy, including subdomains" do
      clear_config([:mrf_simple, :reject], [{"*.rejected.example", "spam"}])

      refute MRF.instance_allowed?("rejected.example")
      refute MRF.instance_allowed?("sub.rejected.example")
      assert MRF.instance_allowed?("fine.example")
    end

    test "only allows accepted hosts when SimplePolicy has an accept list" do
      clear_config([:mrf_simple, :accept], [{"friend.example", ""}])

      assert MRF.instance_allowed?("friend.example")
      refute MRF.instance_allowed?("stranger.example")
    end

    test "ignores the SimplePolicy lists when the policy is not enabled" do
      clear_config([:mrf, :policies], [])
      clear_config([:mrf_simple, :accept], [{"friend.example", ""}])

      assert MRF.instance_allowed?("rejected.example")
      assert MRF.instance_allowed?("stranger.example")
    end

    test "is false without a host" do
      refute MRF.instance_allowed?(nil)
    end
  end
end