feat(upload): add Exif.StripLocation and Exif.ReadDescription filters

Pure-Elixir filters based on exif_stripper. StripLocation also handles
WebP and HEIC/AVIF, which the exiftool filter skipped.

lib/pleroma/upload/filter/exif/read_description.ex

@@ -0,0 +1,32 @@
+# Pleroma: A lightweight social networking server
+# Copyright © 2017-2026 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+
+defmodule Pleroma.Upload.Filter.Exif.ReadDescription do
+  @moduledoc """
+  Reads a description from image metadata when the upload has none yet.
+
+  Checks EXIF ImageDescription, then IPTC Caption-Abstract, then XMP. Blank
+  values and values longer than `[:instance, :description_limit]` are ignored.
+  """
+
+  @behaviour Pleroma.Upload.Filter
+
+  @impl true
+  def filter(%Pleroma.Upload{description: description}) when is_binary(description),
+    do: {:ok, :noop}
+
+  def filter(%Pleroma.Upload{tempfile: file, content_type: "image" <> _} = upload) do
+    max_length = Pleroma.Config.get([:instance, :description_limit])
+
+    case ExifStripper.Description.read_file(file, max_length: max_length) do
+      description when is_binary(description) ->
+        {:ok, :filtered, %{upload | description: description}}
+
+      nil ->
+        {:ok, :noop}
+    end
+  end
+
+  def filter(_), do: {:ok, :noop}
+end

lib/pleroma/upload/filter/exif/strip_location.ex

@@ -0,0 +1,25 @@
+# Pleroma: A lightweight social networking server
+# Copyright © 2017-2026 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+
+defmodule Pleroma.Upload.Filter.Exif.StripLocation do
+  @moduledoc """
+  Strips GPS metadata from uploaded images and overwrites the file in place.
+
+  Supports JPEG, PNG, WebP and ISO-BMFF images (HEIC, AVIF). This is lossless:
+  the image data is not re-encoded. Other image types are left untouched.
+  """
+
+  @behaviour Pleroma.Upload.Filter
+
+  @impl true
+  def filter(%Pleroma.Upload{tempfile: file, content_type: "image" <> _}) do
+    case ExifStripper.GpsStripper.strip_gps_data(file, file) do
+      :ok -> {:ok, :filtered}
+      :noop -> {:ok, :noop}
+      {:error, _} = error -> error
+    end
+  end
+
+  def filter(_), do: {:ok, :noop}
+end