Elixir 1.19: Refactor Logger configuration to what Elixir 1.15+ expects

Elixir 1.19 started emitting warnings about our use of:
config :logger, :console and
config :logger, backends: []
which got split in 1.15 to :default_handler, :default_formatter, and
LoggerBackends.add(backend) respectively.

On Pleroma startup it is now necessary to add the additional logger
backends at runtime (done with configure_logger() in application.ex).
New config key :pleroma, :logger_backends: [] has replaced the older
backends array. The logger_backends package is now used to facilitate
usage of other logger backends besides the default one (:logger_std_h
from OTP).

Warnings were added to Pleroma startup to warn about the usage of
:logger, backends and additional logic was introduced to make addition
of ExSyslogger to admin's configuration less dumb.

Ref: https://hexdocs.pm/logger/1.15.0/Logger.html#module-backends-and-backwards-compatibility

lib/pleroma/application.ex

@@ -43,6 +43,7 @@ defmodule Pleroma.Application do
     # every time the application is restarted, so we disable module
     # conflicts at runtime
     Code.compiler_options(ignore_module_conflict: true)
+    configure_logger()
     Pleroma.Telemetry.Logger.attach()
     Config.Holder.save_default()
     Pleroma.HTML.compile_scrubbers()
@@ -113,6 +114,37 @@ defmodule Pleroma.Application do
     Supervisor.start_link(children, opts)
   end
 
+  def configure_logger do
+    if Application.get_env(:logger, :backends) do
+      Logger.warning(
+        "'config :logger, backends: [...]' is deprecated syntax due to changes in Elixir. Use 'config :pleroma, :logger_backends: [...]' instead."
+      )
+    end
+
+    Config.get([:logger_backends], [])
+    |> Enum.each(fn backend ->
+      backend = backend_to_logger(backend)
+
+      case LoggerBackends.add(backend) do
+        {:ok, _} ->
+          Logger.debug("Successfully added logger backend: #{inspect(backend)}")
+
+        {:error, reason} ->
+          Logger.error("Failed to add logger backend #{inspect(backend)}: #{inspect(reason)}")
+      end
+    end)
+  end
+
+  defp backend_to_logger({:ex_syslogger = backend, name}) do
+    Logger.warning(
+      "Configuration {:#{backend}, :#{name}} is incorrect. Use {ExSyslogger, :#{name}} instead!"
+    )
+
+    {ExSyslogger, name}
+  end
+
+  defp backend_to_logger(backend), do: backend
+
   def load_custom_modules do
     dir = Config.get([:modules, :runtime_dir])